/**
 *  Config class for storing map lists.
 *      Copyright   2023 Anton Tarasenko
 *                  2023 Shtoyan
 *------------------------------------------------------------------------------
 * This file is part of Acedia.
 *
 * Acedia is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, version 3 of the License, or
 * (at your option) any later version.
 *
 * Acedia is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with Acedia.  If not, see <https://www.gnu.org/licenses/>.
 */
class MapList extends AcediaConfig
    perObjectConfig
    config(AcediaMaps);

var public config array<string> map;

protected function HashTable ToData() {
    local int i;
    local ArrayList mapArray;
    local HashTable result;

    result = _.collections.EmptyHashTable();
    mapArray = _.collections.EmptyArrayList();
    for (i = 0; i < map.length; i += 1) {
        mapArray.AddString(map[i]);
    }
    result.SetItem(P("maps"), mapArray);
    _.memory.Free(mapArray);
    return result;
}

protected function FromData(HashTable source) {
    local int i;
    local ArrayList mapArray;

    if (source == none) {
        return;
    }
    mapArray = source.GetArrayList(P("maps"));
    if (mapArray == none) {
        return;
    }
    map.length = 0;
    for (i = 0; i < mapArray.GetLength(); i += 1) {
        map[map.length] = mapArray.GetString(i);
    }
    _.memory.Free(mapArray);
}

protected function DefaultIt() {
    map[0] = "KF-BioticsLab";
    map[1] = "KF-Farm";
    map[2] = "KF-Manor";
    map[3] = "KF-Offices";
    map[4] = "KF-WestLondon";
}

defaultproperties {
    configName = "AcediaMaps"
}