KFZedsReport/Classes/ReportInteraction.uc

/**
 *  Author:      dkanus
 *  Home repo:   https://insultplayers.ru/git/dkanus/KFZedsReport
 */
class ReportInteraction extends Interaction;

var KFZedsReportMut reportMutator;

event NotifyLevelChange() {
    if (master != none) {
        master.RemoveInteraction(self);
    }
}

function PostRender(Canvas canvas) {
    local float textWidth, textHeight;
    local string maxZedsReport, spawnRateReport;
    local string tagWhite, tagGreen;

    if (canvas == none)         return;
    if (reportMutator == none)  return;

    tagWhite = Chr(27)  $ Chr(250)  $ Chr(250)  $ Chr(250);
    tagGreen = Chr(27)  $ Chr(1)    $ Chr(200)  $ Chr(1);
    maxZedsReport = tagWhite $ "Current total zeds"
        @ tagGreen $ reportMutator.repCurrentTotalZeds
        @ tagWhite $ "out of server's total"
        @ tagGreen $ reportMutator.repGameInfo_MaxMonsters;
    spawnRateReport = tagWhite $ "Current spawn rate is"
        @ tagGreen $ reportMutator.repCurrentSpawnRate;
    canvas.TextSize(maxZedsReport, textWidth, textHeight);
    canvas.SetPos(0, 0);
    canvas.DrawText(maxZedsReport);
    canvas.SetPos(0, textHeight + 10);
    canvas.DrawText(spawnRateReport);
}

defaultproperties {
    bVisible = true
}